//キーボード・マウスからの入力無効（誤動作防止）
//※管理者権限が必要
//※強制解除が必要な場合は　Ctrl + Alt + Delete
LOCKHARD(TRUE)

//AzPainterをアクティブに
//複数立ち上げてる場合は多分前面のウィンドウ優先
ACW(GETID("AzPainter","Main"))

//AzPainterが起動していない場合のエラー処理
ID = GETID("AzPainter")
ifb (ID < 0)
	MSGBOX("ウィンドウが見つかりません")
	exitexit
endif

//座標指定選択ウィンドウのIDが取得出来るまで繰り返し
//繰り返し------------ここから
REPEAT

	//Ctrl+Shift+Gで座標指定選択ウィンドウへ
	KBD(VK_SHIFT,DOWN,10)
	KBD(VK_CTRL,DOWN,10)
	KBD(VK_G,CLICK,10)
	KBD(VK_SHIFT,UP,10)
	KBD(VK_CTRL,UP,10)
	
	//変数「APID」にウィンドウIDを取得
	APID = GETID("座標指定選択","#32770")

until (APID > 0)
//繰り返し------------ここまで

//変数「SELX」〜「SELH」それぞれに座標値を取得
SELX = GETSTR(APID,1,0)
SELY = GETSTR(APID,2,0)
SELW = GETSTR(APID,5,0)
SELH = GETSTR(APID,6,0)

//各変数値をタブ区切りでクリップボードに送る
SENDSTR(0,SELX+"<#TAB>"+SELY+"<#TAB>"+SELW+"<#TAB>"+SELH)
////メモ帳派はこっち（カンマ区切りでクリップボードに送る）
//SENDSTR(0,SELX+","+SELY+","+SELW+","+SELH)

//座標指定選択ウィンドウが閉じるまで繰り返し
//繰り返し------------ここから
REPEAT

	//変数「APID」にウィンドウIDを取得
	APID = GETID("座標指定選択","#32770")
	
	//座標指定選択をアクティブに
	ACW(APID)
	
	//ESCキーで座標指定選択を終了
	KBD(VK_ESC,CLICK)

until (APID < 0)
//繰り返し------------ここまで

//変数「EXID」にウィンドウIDを取得
EXID = GETID("Microsoft Excel","XLMAIN")
////その他のプログラムはこっち（変数「EXID」にウィンドウIDを取得）
//EXID = GETID("メモ帳","Notepad")
//EXID = GETID("OpenOffice.org Calc","SALFRAME")
//EXID = GETID("LibreOffice Calc","SALFRAME")

//変数「EXID」をアクティブに
CTRLWIN(EXID,ACTIVATE)

//キーボード・マウスからの入力無効解除
LOCKHARD(FALSE)